Playground

asset fountain "Town fountain" complexity=6
// a plaza fountain: a round basin with a fat rim, a column carrying an upper bowl, a brass nozzle
// shooting a jet that falls back into the bowl, four spouts arcing water into the basin;
// the burst state throws a tall jet for a festival or a coin toss
let R = 1.05..1.3
let stone = sandstone:3|warmstone:2|greystone|terracotta:.5
let metal = brass:3|copper
let H = .7..0.85
 
// basin: a low floor, the water and the fat rim round it
cyl plinth h=.3 r=R+.06 round=.06 color=stone segs=32
cyl water on=plinth at=top h=.03 r=R-.04 color=water segs=32
torus rim on=plinth at=top+(0, .04, 0) R=R r=.14 color=stone*1.04 segs=40 sides=10
 
// the column and the upper bowl
lathe column on=plinth at=top h=H r=.15 prof=[0:1.5 .12:1.1 .2:1 .8:.9 .9:1.2 1:1.3] color=stone segs=16
lathe bowl on=column at=end h=.2 r=.46 prof=[0:.3 .5:.85 1:1] color=stone segs=24
cyl pool on=bowl at=top h=.025 r=.42 color=water segs=24
torus lip on=bowl at=top+(0, .02, 0) R=.44 r=.045 color=stone*1.04 segs=32 sides=8
lathe nozzle on=bowl at=top h=.24 r=.05 prof=[0:1.8 .3:1 .8:.8 1:1.1] color=metal segs=10
 
// four spouts on the bowl, pointing out and a little up
cyl spout x4 on=bowl ring ring0=45 at=(.4, .1, 0) rot=(0, 0, -70) h=.14 r=.035 r2=.028 color=metal segs=8
 
// water
fx jet on=nozzle at=end speed=2.6 spread=7 hz=1.85 n=20 grow=.6
fx splash on=pool at=top hz=1.6 speed=.9 spread=60 n=10
fx jet on=spout at=end speed=1.25 spread=3 hz=2.1 n=15 size=.05
fx burst: jet on=nozzle at=end speed=4.6 spread=5 hz=1.05 n=26 size=.07