Tombstone

1asset tombstone "Tombstone" complexity=2
2// a grave in the crypt's graveyard: a heaped dirt mound and a leaning headstone. Seeds pick the stone
3// (a round-topped slab, a Celtic-style ring cross, a little obelisk or a slab carved with dragon
4// wings), the lean, moss, flowers, a skull, a grave candle, and sometimes a bony hand that has dug
5// its way out and waves.
6let stoneC = greystone:2|rockGrey|sandstone|rockCool
7let dirtC = walnut:2|oak*.7|redwood*.7
8let kind = int(0..3)
9let lean = -9..9
10let hand = chance(.35)
11let deco = int(0..2)
12 
13// the dirt mound
14ball mound r=(.42, .16, .75) half color=dirtC noise=.05 segs=32 rings=12
15ball clod x3 on=mound surf=(i*120+30, 18+i*8) lift=-.02 r=.07 color=dirtC*1.1 segs=8 rings=5
16 
17// the stone
18box base on=mound at=(0, 0, -.68) size=(.62, .12, .22) round=.02 color=stoneC*.85
19box slab on=base at=(0, .1, 0) rot=(lean*.6, 0, lean) size=(.5, .62, .12) round=.03 bands=[.85:stoneC*.92] color=stoneC if=kind==0
20cyl slabTop on=slab at=(0, .62, -.055) rot=(90, 0, 0) h=.11 r=.25 color=stoneC segs=24
21box plaque on=slab at=(0, .3, .055) size=(.32, .18, .02) round=.01 color=stoneC*.75
22box cross on=base at=(0, .1, 0) rot=(lean*.6, 0, lean) size=(.14, .9, .12) round=.02 color=stoneC if=kind==1
23box crossArm on=cross at=(0, .58, 0) size=(.5, .13, .11) round=.02 color=stoneC
24torus crossRing on=cross at=(0, .64, 0) rot=(90, 0, 0) R=.17 r=.035 color=stoneC segs=16 sides=5
25box obelisk on=base at=(0, .1, 0) rot=(lean*.6, 0, lean) size=(.24, .9, .2) round=.02 bands=[.1:stoneC*.85 .14:stoneC] color=stoneC if=kind==2
26cone obTip on=obelisk at=(0, .9, 0) rot=(0, 45, 0) h=.2 r=.17 color=stoneC segs=4
27slab wings on=base at=(0, .1, -.05) rot=(lean*.6, 0, lean) pts=[-.12,0 .12,0 .14,.4 .4,.62 .3,.66 .18,.6 0,.8 -.18,.6 -.3,.66 -.4,.62 -.14,.4] t=.12 round=.025 color=stoneC if=kind==3
28ball wingSkull on=wings at=(0, .55, .09) r=(.08, .075, .06) color=stoneC*1.15 segs=10 rings=6
29 
30// deco by seed: moss, flowers, a skull
31puff moss x2 on=base at=(0, .06, 0) row=(.4, 0, 0) r=.09 color=moss segs=7 rings=5 if=deco==0
32puff flower x3 on=mound at=(.02, .12, -.25) row=(.1, .01, .06) r=.05 color=sel(i, tomato, bubblegum, sunflower) segs=6 rings=4 if=deco==1
33ball skull on=mound at=(.2, .1, .3) rot=(0, -25, 0) r=(.09, .085, .09) color=cream segs=10 rings=7 if=deco==2
34ball sock on=skull at=(.034, .01, .07) mirror r=(.022, .026, .015) color=inkDark segs=6 rings=4
35 
36// a grave candle in a little iron cage, a few grass tufts
37cyl candle on=mound at=(-.24, .06, -.42) h=.16 r=.035 color=cream segs=8
38ball wax on=candle at=(0, .14, 0) r=(.045, .025, .045) color=cream segs=8 rings=4
39ball flame on=candle at=(0, .21, 0) r=(.028, .055, .028) color=sunflower ink=glow segs=8 rings=5
40rod cage x4 on=candle ring ring0=45 at=(.06, 0, 0) to=(0, .3, 0) r=.02 sides=4 color=iron
41cone cageTop on=candle at=(0, .3, 0) h=.08 r=.09 color=iron segs=8
42cone grass x5 on=mound ring ring0=15 at=(.4, -.01, 0) rot=(0, 0, -15) h=.2 r=.06 bend=20 color=sel(i, moss, hedge, moss, lime, hedge) segs=4
43 
44// a hand that has dug its way out
45ball palm on=mound at=(-.12, .12, .2) r=(.075, .045, .055) color=cream segs=10 rings=6 if=hand joint
46rod finger x3 on=palm at=(0, .02, .01) row=(.04, 0, 0) to=(0, .1, .02) r=.02 sides=5 color=cream
47rod thumb on=palm at=(.05, 0, .02) rot=(0, 0, -40) to=(0, .07, 0) r=.02 sides=5 color=cream
48 
49// the hand waves
50anim palm rz keys=[0:0 .1:25 .2:-20 .3:25 .4:-20 .5:0 1:0] hz=.3
51anim palm py keys=[0:0 .1:.03 .5:.03 .6:0 1:0] hz=.3
52