Playground

asset tail_vertebra "Dragon tail vertebra" complexity=4 float
// one vertebra of the ancient dragon's tail, standing as an arch over a corridor: a chunky bone body
// with a tall spine fin raked back toward the tail tip, side wings, and two bowed chevron legs planted
// in rubble. The feet sink 0.4 m below the origin (the scene lifts it 0.4 so traps can sit under it).
// Seeds add a dangling chain lantern, a moss cap or a skull wedged in the rubble.
let H = 4.3..4.7
let W = 1.55
let boneC = cream:3|birch:2|sandstone
let oldC = boneC*.8
let rubbleC = rockGrey:2|rockCool|greystone
let extra = int(0..2)
 
// the bowed legs, planted in rubble
tube leg mirror pts=[W, -.4, 0  W+.12, 1.0, 0  W, 2.3, 0  W*.72, 3.3, 0  .5, H-.75, 0] r=(.26, .36) smooth sides=16 color=boneC
ball knee on=leg at=(W+.12, 1.25, 0) r=(.36, .44, .36) color=boneC segs=16 rings=10
puff mound on=leg at=(W-.05, -.2, 0) r=(.7, .42, .65) color=rubbleC under=rubbleC*.8 segs=16 rings=8
puff stone on=mound at=(.38, .1, .3) r=(.3, .22, .28) color=rubbleC*1.1 segs=10 rings=6
 
// the body, discs fore and aft, side wings and the raked spine fin
box body at=(0, H-1.25, 0) size=(1.4, 1.15, 1.45) round=.4 bev=2 bands=[.2:boneC .8:oldC] color=boneC
cyl disc x2 on=body at=(0, .58, -.06) row=(0, 0, 1.52) rot=(90, 0, 0) h=.12 r=.46 color=oldC segs=16
cone wing on=body at=(.6, .7, 0) mirror rot=(0, 0, -95) h=.85 r=.3 r2=.1 depth=.6 color=boneC segs=10
cone fin on=body at=(0, 1.0, .1) rot=(22, 0, 0) h=1.5 r=.46 r2=.1 depth=.42 color=boneC segs=12
ball finTip on=fin at=(0, 1.5, 0) r=(.12, .16, .1) color=boneC segs=8 rings=5
 
// extras by seed
rod chain on=body at=(0, .05, 0) to=(0, -1.3, 0) r=.035 sides=5 color=iron if=extra==0 joint
cyl lamp on=chain at=end+(0, -.4, 0) h=.07 r=.13 color=iron segs=8
ball glowL on=lamp at=(0, .19, 0) r=(.14, .18, .14) color=glow ink=glow segs=8 rings=5 joint
cone lampLid on=lamp at=(0, .38, 0) h=.16 r=.2 color=iron segs=6
puff mossCap on=body at=(0, 1.0, -.25) r=(.62, .22, .5) color=moss segs=10 rings=6 if=extra==1
ball skull on=mound at=(-.3, .3, .35) r=(.2, .17, .19) color=boneC segs=10 rings=7 if=extra==2
ball eyeL on=skull at=(.07, .02, .15) mirror r=(.055, .06, .04) color=inkDark ink=none segs=6 rings=4
 
anim chain rz sin amp=4 hz=.4
anim glowL s sin amp=.12 hz=1.8