Playground

asset office_bookshelf "Office bookshelf" complexity=4
// a tall open bookshelf backed onto a wall: a chunky frame with four shelves; rows of mixed books in
// toy colours (tall and short, one leaning), a stack lying flat, a small plant, a trophy and a pair
// of box files; the back faces -Z, the books face +Z
let W = 1.4..1.6
let H = 1.9..2.05
let Dp = .38
let woodC = birch:3|oak:2|white|walnut
let backC = woodC*.86
let c1 = cherry|cobalt|teal
let c2 = sunflower|tangerine|coral
let c3 = mint|lime|bottle
let c4 = grape|lilac|pink
let c5 = navy|walnut|cream
 
// the frame
box side at=(W/2-.035, 0, 0) mirror size=(.07, H, Dp) round=.02 color=woodC
box top at=(0, H-.06, 0) size=(W-.07, .06, Dp) round=.02 color=woodC
box plinth at=(0, 0, .01) size=(W-.07, .1, Dp-.04) round=.02 color=backC
box backing at=(0, .1, -Dp/2+.02) size=(W-.08, H-.17, .03) round=.01 color=backC
box shelf x3 at=(0, .1+(H-.16)*.5-.025, 0) row=(0, (H-.16)/4, 0) size=(W-.08, .04, Dp-.03) round=.012 color=woodC
 
// books on the bottom (plinth) row: tall binders
box book1 x6 on=plinth at=(-W*.27, .1, -.02) row=(.085, 0, 0) size=(.07, sel(i, .32, .3, .34, .28, .32, .3, .33), .26) round=.012 color=sel(i, c1, c2, c3, c4, c5, c1, c3)
box file x2 on=plinth at=(W*.27, .1, -.02) row=(.13, 0, 0) size=(.11, .3, .27) round=.015 bands=[.7:white .8:c2] color=c2
 
// the three shelves: books, a stack, a plant, a trophy
box book2 x6 on=shelf at=(-W*.2, .04, -.02) row=(.075, 0, 0) size=(.06, sel(i, .26, .22, .28, .24, .2, .27, .23, .25), .22) round=.012 color=sel(i+parent.i*3, c2, c4, c1, c3, c5, c2, c1, c4, c3, c5, c2, c1, c4, c3) if=parent.i!=1
box lean on=shelf at=(W*.15, .04, -.02) roll=-18 size=(.06, .25, .22) round=.012 color=c4 if=parent.i!=1
box flat x2 on=shelf at=(W*.32, .04, -.02) chain=(0, .05, 0) rot=(0, 6, 0) size=(.26, .05, .2) round=.012 color=sel(i, c5, c1, c2) if=parent.i!=1
lathe pot on=shelf at=(-W*.3, .04, 0) h=.14 r=.07 prof=[0:.75 1:1] color=terracotta segs=14 if=parent.i==1
puff fern on=pot at=(0, .17, 0) r=(.12, .1, .11) color=leafA segs=12 rings=7
ball trail x2 on=pot ring ring0=60 at=(.07, .08, 0) r=(.04, .08, .04) color=leafA segs=8 rings=5
cyl cupbase on=shelf at=(-W*.08, .04, 0) h=.05 r=.06 color=walnut segs=12 if=parent.i==1
lathe cup on=cupbase at=(0, .05, 0) h=.18 r=.07 prof=[0:.25 .3:.25 .45:.9 1:1] color=brass segs=16
box book3 x4 on=shelf at=(W*.08, .04, -.02) row=(.075, 0, 0) size=(.06, sel(i, .24, .27, .22, .26), .22) round=.012 color=sel(i, c3, c1, c4, c2) if=parent.i==1